home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 4: GNU Archives / Linux Cubed Series 4 - GNU Archives.iso / gnu / dclshar < prev    next >
Encoding:
Text File  |  1996-11-17  |  1004 b   |  45 lines
  1. #!/bin/csh -f
  2. #    Make a shar-type .COM file for VAX/VMS systems,
  3. #    so we can transfer whole filesystem heirarchies
  4. #    back and forth.  On VMS, unpack via
  5. #
  6. #        $ @SHARFILE.COM
  7. #
  8. #    On Unix, suggest you generate a tape via something
  9. #    like
  10. #
  11. #    % dclshar * | dd of=/dev/rmt8 cbs=240 obs=4800 conv=block
  12. #
  13. set myname = $0
  14.  
  15. set noglob
  16. echo '$\! This is a DCL shar-type archive created by Unix dclshar.'
  17. foreach unix ($argv)
  18.     @ dirflag = -d $unix
  19.     if ( $dirflag ) then
  20.     set name
  21.     set dir = $unix
  22.     else
  23.     set name = $unix:t
  24.     set dir = $unix:h
  25.     if ( "$dir" == "$unix" ) set dir
  26.     endif
  27.  
  28.     set dcldir = `echo XXX$dir | /bin/sed -e s:\\.:_:g -e s:^XXX/:: -e s:^XXX:.: -e s:/:.:g`
  29.     set dcldir = "[$dcldir]"
  30.     if ( "$dcldir" == "[]" || "$dcldir" == "[.]" ) set dcldir
  31.     set dclname = "${dcldir}$name"
  32.  
  33.     echo \$\!
  34.     if ( $dirflag ) then
  35.     echo \$CREATE/DIRECTORY $dcldir
  36.     ( unset noglob; $myname {$unix}/* )
  37.     else
  38.     echo \$CREATE $dclname
  39.     echo \$DECK
  40.     /bin/cat $unix
  41.     echo \$EOD
  42.     endif
  43. end
  44.  
  45.